#!/bin/tcsh
###############################################################################
# This script sets thing up to run Synopsys VCS for verilog or vhdl simulation.
# Remember to specify a file containing the list of hdl source files including
# the top testbench file. Use the -gui switch to use the gui. 
# Erik Brunvand, University of Utah
###############################################################################
setenv CADPUB /uusoc/facility/cad_common/
setenv CADSETUPS ${CADPUB}/local/setups/F08

# store the argument for hdl source list
setenv SOURCELIST $1

#if arguments not specified prompt for proper syntax
if ("$SOURCELIST" == "") then
   echo "sim-vcs - Opens Synopsys VCS for hdl simulation."
   echo "          "
   echo "Usage   : sim-vcs file.v <other switches>" 
   echo "          file.v is the verilog file to simulate" 
   echo "  "
   echo "Usage   : sim-vcs -f f1 <other switches>"
   echo "          f1 is a file containing a list of Verilog source files"
   echo "          including the top testbench file."
   echo "  " 
   echo " After running sim-vcs, run the compiled simulator with the"
   echo " command 'simv'" 
   echo "  "
   echo "Use the -gui switch before -f for a version of simv that  "
   echo "starts the dve GUI environment. "
   echo "  "
   exit
endif

#setup to run synopsys
source ${CADSETUPS}/setup-synopsys

# Fix a couple things that vcs needs... 
unsetenv LD_LIBRARY_PATH
echo OS is set to ${OS}
switch ($OS)

    case suse*:
	setenv VCS_ARCH_OVERRIDE suse32
	echo "VCS_ARCH_OVERRIDE set to suse32"
    breaksw

    case linux:
	setenv VCS_ARCH_OVERRIDE linux
	echo "VCS_ARCH_OVERRIDE set to linux"
    breaksw

    case amd64:
	setenv VCS_ARCH_OVERRIDE amd64
	echo "VCS_ARCH_OVERRIDE set to amd64"
    breaksw
endsw

# Start vcs for simulation after compiling the source files 
vcs +v2k +neg_tchk -l vcs.log $argv